Introduction to Visual Basic Built-In Functions

Overview of Built-In Procedure

Introduction 

A procedure is referred to as "built-in" if it shipped with its programming language. To make your job a little easier, the Visual Basic language is equipped with many procedures that you can use right away in your program. Based on this, before creating your own procedure, first check whether the functionality you are looking for is already implementing in one of the available procedures because those that ship with the Visual Basic language are highly reliable and should be preferred.

Before using a built-in procedure, you must of course be familiar with it. This comes either by consulting the documentation or by experience. This means that you must know its name, its argument(s), its return value, and its role. The Visual Basic programming language provides one of the richest libraries you will ever see. In fact, it is the richest of the .NET-based languages, giving you access to functions that are not directly available to other languages such as C# or C++/CLI. Because there so many of those functions, we will review only the most usually used. Eventually, when necessary, in other lessons, we may introduce new ones.

You may recall that when studying data types, we saw that each had a corresponding function used to convert a string value or an expression to that type. As a reminder, the general syntax of the conversion functions is:

ReturnType = FunctionName(Expression)

The Expression could be of any kind. For example, it could be a string or expression that would produce a value such as the result of a calculation. The conversion function would take such a value, string, or expression and attempt to convert it. If the conversion is successful, the function would return a new value that is of the type specified by the ReturnType in our syntax.

The conversion functions are as follows:

These functions allow you to convert a known value to a another type. Besides these functions, the Visual Basic language provides a function named CType. Its syntax is:

CType(expression, typename)

As you can see, the CType() function takes two arguments. The first argument is the expression or the value that you want to convert. An example could be name of a variable or a calculation:

CType(250.48 * 14.05, ...)

The second argument is the type of value you want to convert the first argument to. From what have learned so far, this second argument can be one of the data types we reviewed in Lesson 3. Here is an example:

CType(250.48 * 14.05, Single)

If you choose one of the Visual Basic language's data types, the expression produced by the first argument must be able to produce a value that is conform to the type of the second argument:

• The conversion from the first argument to the type of the second argument must be possible: the value produced by the first must be convertible to the second arguments. For example, if the first argument is a calculation, the second argument must be a number-based data type. In the same way, you cannot convert a date to a number-based type
• If the first argument is a number or the result of a calculation, its resulting value must be lower than or up to the range of values of the second argument. Here is an example:
   

  Public Module Exercise Public Function Main() As Integer MsgBox(CType(250.48 * 14.05, Single)) Return 0 End Function End Module This would produce:

• If the first argument is a number or the result of a calculation that produces an integer or a floating-point number, its resulting value must be convertible to an integer or a floating point number up to the range of values of the second argument. Here is an example:
   

  Public Module Exercise Public Function Main() As Integer MsgBox(CType(7942.225 * 202.46, UInteger)) Return 0 End Function End Module This would produce:

• If the first argument is a number or the result of a calculation that produces an integer or a floating-point number, the second argument is a number-based data type but whose range cannot hold the resulting value of the first argument, the conversion would not be allowed (the conversion will fail):
   

After the CType() function has performed its conversion, it returns a value that is the same category as the second argument. For example, you can call a CType() function that converts an expression to a long integer. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As Long

        Number = CType(7942.225 * 202.46, Long)

        Return 0
    End Function

End Module

The function can also return a different type, as long as its type can hold the value produced by the expression. Here are two examples:

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As UInteger

        Number = CType(7942.225 * 202.46, Long)

        Return 0
    End Function

End Module

Or

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As Single

        Number = CType(7942.225 * 202.46, Long)

        Return 0
    End Function

End Module

If you try storing the returned value into a variable that cannot hold it, you would receive an error:

In Lesson 3, we saw that different data types are used to store different values. To do that, each data type requires a different amount of space in the computer memory. To know the amount of space that a data type or a variable needs, you can call the Len() function. Its syntax is:

Public Shared Function Len( _
   ByVal Expression As { Boolean | Byte | SByte | Char | Double |
   Integer | UInteger | Long | ULong | Object | Short | UShort |
   Single | String | DateTime | Decimal } _
) As Integer

To call this function, you can declare a variable with a data type of your choice and optionally initialize with the appropriate value, then pass that variable to the function. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim Value As Integer

        Value = 774554

        MsgBox(Value & " needs " & Len(Value) & " bytes to be stored in memory.")
        Return 0
    End Function

End Module

This would produce:

If you have a decimal number but are interested only in the integral part, to assist you with retrieving that part, the Visual Basic language provides the Int() and the Fix() functions. Their syntaxes are:

Public Shared Function Int( _
    ByVal Number As { Double | Integer | Long | 
		      Object | Short | Single | Decimal }) _
    As { Double | Integer | Long | Object | Short | Single | Decimal }
Public Shared Function Fix( _
    ByVal Number As { Double | Integer | Long | 
		      Object | Short | Single | Decimal }) _
    As { Double | Integer | Long | Object | Short | Single | Decimal }

Each function must take one argument. The value of the argument must be number-based. This means it can be an integer or a floating-point number. If the value of the argument is integer-based, the function returns the (whole) number. Here is an example

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As Integer

        Number = 286345
        MsgBox(Int(Number))

        Return 0
    End Function

End Module

This would produce:

If the value of the argument is a decimal number, the function returns only the integral part. Here is an example

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As UInteger

        Number = 7942.225 * 202.46
        MsgBox(Int(Number))

        Return 0
    End Function

End Module

This would produce:

This function always returns the integral part only, even if you ask it to return a floating-point-based value. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim Number As Single

        Number = 286345.9924
        MsgBox(Int(Number))

        Return 0
    End Function

End Module

This would produce:

A random number is a value that is not known in advanced until it is generated by the compiler. To assist you with getting a random number, the Visual Basic language provides a function named Rnd. Its syntax is:

Public Shared Function Rnd[(Number)] As Single

This function takes an optional argument. If the argument is not passed, the compiler would simply generate a positive decimal number between 0 and 1. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        
        MsgBox("Random Number: " & Rnd())

        Return 0
    End Function

End Module

This would produce:

You may wonder how the compiler generates a random number. Without going into all the details, in most cases, a compiler refers to the system clock (the clock of the computer on which the application is). It uses a certain algorithm to get that number.

If you call the function like we did above, every time you execute the application, you are likely to get the same result. Depending on how you want to use the number, in some cases, you may want to get a different number every time. To support this, random arithmetic supports what is referred to as a seed. If you do not use a seed, the compiler would keep the same number it generated from the system clock the first time it was asked to produce a random number. Seeding allows the compiler to reset this mechanism, which would result in a new random number.

To assist you with seeding, the Visual Basic language provides a function named Randomize. Its syntax is:

Public Shared Sub Randomize ([ Number ])

This function takes one optional argument. If you can this function without the argument, the compiler would refer to the system clock to generate the new random number. Of course, to get the number, you must call this function before calling Rnd(). Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Randomize()

        MsgBox("Random Number: " & Rnd())

        Return 0
    End Function

End Module

This time, every time the Rnd() function is called, the compiler generates a new number. Instead of letting the compiler refer to the system clock, you can provide your own seed value. To do this, pass a number to the Randomize() function.

We mentioned that the Rnd() function generates a number between 0 and 1. Of course, in some cases you will want the number to be in a higher range, such as between 0 and 100 or between 0 and 100000. All you have to do is to multiply the result to a number of your choice. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Randomize()

        MsgBox("Random Number: " & CStr(100 * Rnd()))

        Return 0
    End Function

End Module

This would produce:

Also notice that the result is a decimal number. If you interested in only the integral part of the number, you can call the Int() function.

Besides Visual Basic's own combination of the Rnd() and the Randomize() functions, the .NET Framework supports random numbers in another way (using Random).

The Visual Basic language has a strong support for date values. It is equipped with its own data type named Date. To create and manipulate dates, you have various options. To declare a date variable, you can use either the Date or the DateTime data types.

While Date is a true data type, DateTime is a class but, even though we have not studied classes yet, we can start using DateTime. We will restrict ourselves to using it only as a data type.

In Lesson 3, we saw how to declare a date variable using Date. We also saw that, if you already know the components of the date value you want to use, you can include them between two # signs but following the rules of a date format from the Regional Settings of Control Panel. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date

        DateHired = # 02/08/2003 #

        MsgBox("Date Hired: " & DateHired)
        Return 0
    End Function

End Module

This would produce:

An alternative to initializing a date variable is to use a function named DateSerial. Its syntax is:

Public Function DateSerial(ByVal [Year] As Integer, _
   			   ByVal [Month] As Integer, _
   			   ByVal [Day] As Integer) As DateTime

As you can see, this function allows you to specify the year, the month, and the day of a date value, of course without the # signs. When it has been called, this function returns a Date value. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date

        DateHired = DateSerial(2003, 02, 08)

        MsgBox("Date Hired: " & DateHired)
        Return 0
    End Function

End Module

When passing the values to this function, you must restrict each component to the allowable range of values. You can pass the year with two digits from 0 to 99. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim DateHired As Date

        DateHired = DateSerial(03, 2, 8)

        MsgBox("Date Hired: " & DateHired)
        Return 0
    End Function

End Module

If you pass the year as a value between 0 and 99, the compiler would refer to the clock on the computer to get the century. At the time of this writing (in 2008), the century would be 20 and the specified year would be added, which would produce 2003. To be more precise and reduce any confusion, you should always pass the year with 4 digits.

The month should (must) be a value between 1 and 12. If you pass a value higher than 12, the compiler would calculate the remainder of that number by 12 (that number MOD 12 = ?). The result of the integer division would be used as the number of years and added to the first argument. The remainder would be used as the month of the date value. For example, if you pass the month as 18, the integer division would produce 1, so 1 year would be added to the first argument. The remainder is 6 (18 MOD 12 = 6); so the month would be used as 6 (June). Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim DateHired As Date

        DateHired = DateSerial(2003, 18, 8)
        MsgBox("Date Hired: " & DateHired)

        Return 0
    End Function

End Module

This would produce:

As another example, if you pass the month as 226, the integer division (226 \ 12) produces 18 and that number would be added to the first argument (2003 + 18 = 2021). The remainder of 226 to 12 (226 MOD 12 = 10) is 10 and that would be used as the month. Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim DateHired As Date

        DateHired = DateSerial(2003, 226, 8)
        MsgBox("Date Hired: " & DateHired)

        Return 0
    End Function

End Module

This would produce:

If the month is passed as 0, it is considered 12 (December) of the previous year. If the month is passed as -1, it is considered 11 (November) of the previous year and so on. If the month is passed as a number lower than -11, the compiler would calculate its integer division to 12, add 1 to that result, use that number as the year, calculate the remainder to 12, and use that result as the month.

Depending on the month, the value of the day argument can be passed as a number between 1 and 28, between 1 and 29, between 1 and 30, or between 1 and 31. If the day argument is passed as a number lower than 1 or higher than 31, the compiler uses the first day of the month passed as the second argument. This is 1. If the day is passed as -1, the day is considered the last day of the previous month of the Month argument. For example, if the Month argument is passed as 4 (April) and the Day argument is passed as -1, the compiler would use 31 as the day because the last day of March is 31. If the Month argument is passed as 3 (March) and the Day argument is passed as -1, the compiler would refer to the Year argument to determine whether the year is leap or not. This would allow the compiler to use either 28 or 29 for the day value. The compiler uses this algorithm for any day value passed as the third argument when the number is lower than 1.

If the Day argument is passed with a value higher than 28, 29, 30, or 31, the compiler uses this same algorithm in reverse order to determine the month and the day.

If you have a value such as one provided as a string and you want to convert it to a date, you can call the CDate() function. Its syntax is:

Function CDate(Value As Object) As Date

This function can take any type of value but the value must be convertible to a valid date. If the function succeeds in the conversion, it produces a Date value. If the conversion fails, it produces an error.

As seen so far, a date is a value made of at least three parts: the year, the month, and the day. The order of these components and how they are put together to constitute a recognizable date depend on the language and they are defined in the Language and Regional Settings in Control Panel.

The Visual Basic language supports the year of a date ranging from 1 to 9999. This means that this the range you can consider when dealing with dates in your applications. In most operations, when creating a date, if you specify a value between 1 and 99, the compiler would use the current century for the left two digits. This means that, at the time of this writing (2008), a year such as 4, 04, or 44 would result in the year 2004. In most cases, to be more precise, you should usually or always specify the year with 4 digits.

If you have a date value whose year you want to find out, you can call the Year() function. Its syntax is:

Public Function Year(ByVal DateValue As DateTime) As Integer

As you can see, this function takes a date value as argument. The argument should hold a valid date. If it does, the function returns the numerical year of a date. Here is an example:

Public Module Exercise
    Public Function Main() As Integer

        Dim DateHired As Date = #2/8/2004#

        MsgBox("In the job since " & Year(DateHired))

        Return 0
    End Function

End Module

This would produce:

The month part of a date is a numeric value that goes from 1 to 12. When creating date, you can specify it with 1 or 2 digits. If the month is between 1 and 9 included, you can precede it with a leading 0.

If you have a date value and want to get its month, you can call the Month() function. Its syntax is:

Public Function Month(ByVal DateValue As DateTime) As Integer

This function takes a Date object as argument. If the date is valid, the function returns a number between 1 and 12 for the month. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date = #2/8/2004#

        MsgBox("Month hired " & Month(DateHired))

        Return 0
    End Function

End Module

This would produce:

As mentioned already, the Month function produces a numeric value that represents the month of a date. In a year, a month is recognized by an index in a range from 1 to 12. A month has also a name. The name of a function is given in two formats: complete or short. These are:

Instead of getting the numeric index of the month of a date, if you want to get the name of the month, you can call a function named MonthName. Its syntax is:

Public Function MonthName(ByVal Month As Integer, _
   			  Optional ByVal Abbreviate As Boolean = False) As String

This function takes one required and one optional argument. The required argument must represent the value of a month. If it is valid, this function returns the corresponding name. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date = #2/8/2004#

        MsgBox("Day hired " & MonthName(Month(DateHired)))

        Return 0
    End Function

End Module

This would produce:

The second argument allows you to specify whether you want to get the complete or the short name. The default is the complete name, in which case the default value of the argument is False. If you want to get the short name, pass the second argument as True. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date = #2/8/2004#

        MsgBox("Month hired " & MonthName(Month(DateHired), True))

        Return 0
    End Function

End Module

The day is a numeric value in a month. Depending on the month (and the year), its value can range from 1 to 29 (February in a leap year), from 1 to 28 (February in a non-leap year), from 1 to 31 (January, March, May, July, August, October, and December), or from 1 to 30 (April, June, September, and November).

If you have a date value and you want to know its day in a year, you can call the Day() function. Its syntax is:

Public Function Day(ByVal DateValue As DateTime) As Integer

This function takes a date as argument. If the date is valid, the function returns the numeric day in the month of the date argument. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DateHired As Date = #2/8/2004#

        MsgBox("Day hired " & Day(DateHired))

        Return 0
    End Function

End Module

This would produce:

A week is a combination of 7 consecutive days of a month. Each day can be recognized by an index from 1 to 7 (1, 2, 3, 4, 5, 6, 7). The day of each index is recognized by a name. In US English, the first day has an index of 1 is named Sunday while the last day with an index of 7 is named Monday. Like the months of a year, the days of a week have long and short names. These are:

These are the default in US English. In most calculations, the Visual Basic language allows you to specify what day should be the first in a week.

To get the name of the day of a week, you can a function named WeekdayName. Its syntax is:

Public Function WeekdayName( _
   ByVal Weekday As Integer, _
   Optional ByVal Abbreviate As Boolean = False, _
   Optional ByVal FirstDayOfWeekValue As FirstDayOfWeek = FirstDayOfWeek.System _
) As String

This function takes one required and two optional arguments. The required argument must be, or represent, a value between 0 and 7. If you pass it as 0, the compiler will refer to the operating system's language to determine the first day of the week, which in US English is Sunday. Otherwise, if you pass one of the above indexes, the function would return the corresponding name of the day. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        MsgBox("Day hired: " & WeekdayName(4))

        Return 0
    End Function

End Module

This would produce:

If you pass a negative value or a value higher than 7, you would receive an error.

The second argument allows you to specify whether you want to get the complete or the short name. The default value of this argument is False, which produces a complete name. If you want a short name, pass the second argument as True. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        MsgBox("Day hired: " & WeekdayName(4, True))

        Return 0
    End Function

End Module

As mentioned already, the Visual Basic language allows you to specify what days should be the first day of the week. This is the role of the third argument.

The Visual Basic language supports time values. To create a time value, you can declare a variable of type Date. To initialize the variable, create a valid value using the rules specified in the Regional and language Settings of Control Panel, and include that value between two # signs. Here is an example;

Public Module Exercise

    Public Function Main() As Integer

        Dim DepositTime As Date = #7:14#

        MsgBox("Deposit Time: " & DepositTime)

        Return 0
    End Function

End Module

This would produce:

Instead of including the time in # signs, you can also provide it as a string. To support this, the Visual Basic language provides a function named TimeValue. Its syntax is:

Public Function TimeValue(ByVal StringTime As String) As DateTime

This function expects a valid time as argument. If that argument is valid, the function returns a time value. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DepositTime As Date = TimeValue("7:14")

        MsgBox("Deposit Time: " & DepositTime)

        Return 0
    End Function

End Module

As an alternative to initializing a time variable, you can call a function named TimeSerial. Its syntax is:

Public Function TimeSerial(ByVal Hour As Integer, _
   			   ByVal Minute As Integer, _
   			   ByVal Second As Integer) As DateTime

This function allows you to specify the hour, the minute, and the second values of a time. If you pass valid values, the function returns a time. Here is an example:

Public Module Exercise

    Public Function Main() As Integer

        Dim DepositTime As Date

        DepositTime = TimeSerial(7, 14, 0)

        MsgBox("Deposit Time: " & DepositTime)

        Return 0
    End Function

End Module

In US English, a time is made of various parts. The first of them is the hour. The time is a 24th spatial division of a day. It is represented by a numeric value between 0 and 23. When creating a time value, you specify the hour on the left side. To get the hour of a valid time, you can call a function named Hour. Its syntax is:

Public Function Hour(ByVal TimeValue As DateTime) As Integer

This function takes a time value as argument. If a valid time is passed, the function returns the hour part.

An hour is divided in 60 parts. Each part is called a minute and is represented by a numeric value between 0 and 59. If you have a time value and want to get its minute part, you can call a function named Minute. Its syntax is:

Public Function Minute(ByVal TimeValue As DateTime) As Integer

When calling this function, pass it a time value. If the argument holds a valid value, the function returns a number between 0 and 59 and that represents the minutes.

A minute is divided in 60 parts and each part is called a second. It is represented by a numeric value between 0 and 59. If you have a time value and want to extract a second part from it, you can call the Second() function named . Its syntax is:

Public Function Second(ByVal TimeValue As DateTime) As Integer

If you call this function, pass a valid time. If so, the function would return a number represents the seconds part.

Because dates and times are primarily considered as normal values, there are various operations you can perform on them. You can add or subtract a number of years or add or subtract a number of months, etc. The Visual Basic language provides its own mechanisms for performing such operations thanks to its vast library of functions.

To support the addition of a value to a date or a time, the Visual Basic language provides a function named DateAdd. In the Visual Basic language, the DateAdd() function comes in two versions whose syntaxes are:

Public Overloads Function DateAdd( _
   ByVal Interval As DateInterval, _
   ByVal Number As Double, _
   ByVal DateValue As DateTime _
) As DateTime
' -or-
Public Overloads Function DateAdd( _
   ByVal Interval As String, _
   ByVal Number As Double, _
   ByVal DateValue As Object _
) As DateTime

This function takes three arguments that all are required.

Because we have not studied enumerations and classes yet, we will ignore the first version.

The DateValue argument is the date or time value on which you want to perform this operation. It must be a valid Date or DateTime value.

The Interval argument is passed as a string. It specifies the kind of value you want to add. This argument will be enclosed between double quotes and can have one of the following values:

The Number argument specifies the number of Interval units you want to add to the DateValue value. If you set it as positive, its value will be added. Here are examples:

Public Module Exercise

    Public Function Main() As Integer
        Dim LoanStartDate As Date = #6/10/1998#
        Dim DepositTime As Date = TimeValue("7:14:00")

        MsgBox("Loan Length: " & DateAdd("yyyy", 5, LoanStartDate))
        MsgBox("Time Ready: " & DateAdd("h", 8, DepositTime))

        Return 0
    End Function

End Module

This would produce:

Instead of adding a value to a date or a time value, you may want to subtract. To perform this operation, pass the Number argument as a negative value. Here are examples:

Public Module Exercise

    Public Function Main() As Integer
        Dim LoanPayDate As Date = #8/12/2008#
        Dim TimeReady As Date = TimeValue("17:05")

        MsgBox("Loan Length: " & DateAdd("m", -48, LoanPayDate))
        MsgBox("Time Deposited: " & DateAdd("n", -360, TimeReady))

        Return 0
    End Function

End Module

This would produce:

Another valuable operation performed consists of finding the difference between two date or time values. To help you perform this operation, the Visual Basic language provides a function named DateDiff. This function allows you to find the number of seconds, minutes, hours, days, weeks, months, or years from two valid date or time values. The DateDiff function takes 5 arguments, 3 are required and 2 are optional.

The formula of the function is

Public Overloads Function DateDiff( _
    ByVal Interval As [ DateInterval | String ], _
    ByVal Date1 As DateTime, _
    ByVal Date2 As DateTime, _
    Optional ByVal DayOfWeek As FirstDayOfWeek = FirstDayOfWeek.Sunday, _
    Optional ByVal  WeekOfYear As FirstWeekOfYear = FirstWeekOfYear.Jan1 _
) As Long

This function takes five arguments, three of which are required and two are optional.

The Date1 argument can be the start date or start time. The Date2 argument can be the end date or end time. These two arguments can also be reversed, in which case the Date2 argument can be the start date  or start time and the Date1 argument would be the end date or end time. These two values must be valid date or time values

The Interval argument specifies the type of value you want as a result. This argument will be enclosed between double quotes and can have one of the following values:

Here is an example:

Public Module Exercise

    Public Function Main() As Integer
        Dim LoanStartDate As Date = #8/12/2003#
        Dim LoanEndDate As Date = #10/5/2008#
        Dim Months As Long = DateDiff("m", LoanStartDate, LoanEndDate)

        MsgBox("Loan Start Date: " & vbTab & LoanStartDate & vbCrLf & _
               "Loan End Date: " & vbTab & LoanEndDate & vbCrLf & _
               "Loan Length: " & vbTab & Months & " months")

        Return 0
    End Function

End Module

This would produce:

By default, the days of a week are counted starting on Sunday. If you want to start counting those days on another day, supply the Option1 argument using one of the following values: vbSunday, vbMonday, vbTuesday, vbWednesday, vbThursday, vbFriday, vbSaturday. There are other variances to that argument.

If your calculation involves weeks or finding the number of weeks, by default, the weeks are counted starting January 1st. If you want to count your weeks starting at a different date, use the Option2 argument to specify where the program should start.

Function DDB( _
   ByVal Cost As Double, _
   ByVal Salvage As Double, _
   ByVal Life As Double, _
   ByVal Period As Double, _
   Optional ByVal Factor As Double = 2.0 _
) As Double

Public Module Exercise

    Public Function Main() As Integer
        Dim BoatPrice As Double
        Dim EndValue As Double
        Dim LifeTime As Double
        Dim Depreciation As Double

        BoatPrice = 22455
        EndValue = 5000
        LifeTime = 60 ' Months
        Depreciation = DDB(BoatPrice, EndValue, LifeTime, 2)

        MsgBox("=-= Double Declining Balance =-=" & vbCrLf & _
               "Boat Price: " & vbTab & BoatPrice & vbCrLf & _
               "End Value: " & vbTab & EndValue & vbCrLf & _
               "Life Time: " & vbTab & LifeTime & " months" & vbCrLf & _
               "End Balance: " & vbTab & Depreciation)
        Return 0
    End Function

End Module

Function SLN( _
   ByVal Cost As Double, _
   ByVal Salvage As Double, _
   ByVal Life As Double _
) As Double

Public Module Exercise

    Public Function Main() As Integer
        Dim GuitarPrice As Double
        Dim EndValue As Double
        Dim LifeTime As Double
        Dim Depreciation As Double

        GuitarPrice = 1250
        EndValue = 250
        LifeTime = 44 ' Months
        Depreciation = SLN(GuitarPrice, EndValue, LifeTime)

        MsgBox("=-= Straight Line Method =-=" & vbCrLf & _
               "Guitar Price: " & vbTab & GuitarPrice & vbCrLf & _
               "End Value: " & vbTab & EndValue & vbCrLf & _
               "Life Time: " & vbTab & LifeTime & " months" & vbCrLf & _
               "Depreciation: " & vbTab & Depreciation)
        Return 0
    End Function

End Module

Year => 1, 2, 3, 4, and 5

Sum = 1 + 2 + 3 + 4 + 5 = 15

SYD(cost, salvage, life, period)

FV(Rate, Periods, Payment, PresentValue, PaymentType)

NPer(Rate, Payment, PresentValue, FutureValue, PaymentType);

Pmt(Rate, NPeriods, PresentValue, FutureValue, PaymentType)

IPmt(Rate, 
    Period, NPeriods, PresentValue, FutureValue, PaymentType)

PPMT(Rate, Period, NPeriods, 
      PresentValue, FutureValue, PaymentType)

PV(Rate, NPeriods, Payment, FutureValue, PaymentType)

RateE(NPeriods, Payment, PresentValue, FutureValue, PaymentType, Guess)

IRR(Values, Guess)

NPV(Rate, Value1, Value2, ...)

vbc /target:library NameOfFile.vb

vbc /target:library /out:DesiredNameOfLibrary.dll NameOfFile.vb